Sie können Excel verwenden, um Informationen in kleinere Teile zu zerlegen. Das Finden der benötigten Daten und deren Bearbeitung ist ein wichtiges Ziel für viele Excel-Benutzer.
Wenn Sie den vollständigen Namen einer Person haben, müssen Sie sich möglicherweise nur auf ihren Vornamen oder ihren Nachnamen konzentrieren. Wenn Sie beispielsweise eine freundliche automatische E-Mail an Ihre Kunden senden, müssen Sie ihre Vornamen verwenden, um zu vermeiden, dass sie unpersönlich klingen. Wenn Sie sich eine Liste von Umfrageteilnehmern ansehen, kann es wichtig sein, nur ihre Nachnamen zu verwenden oder ihre Nachnamen zu verbergen, um die Anonymität zu wahren.
Excel macht diesen Prozess unkompliziert, und es gibt viele verschiedene Ansätze, die Sie wählen können. Hier ist ein Tutorial, das Ihnen hilft, mithilfe von Formeln separate Spalten für den Vornamen und den Nachnamen zu erstellen. Wir behandeln auch das Thema Zweitnamen.
Excel-Formeln zum Aufteilen von Namen in Teile
Wo fängst du an?
Vornamen trennen
Dies ist die generische Formel:
=LEFT(cell,FIND(” “,cell,1)-1)
Um es auszuführen, ersetzen Sie cell mit dem Zellzeiger, der den ersten vollständigen Namen enthält, den Sie aufteilen möchten. In diesem Beispiel möchten Sie B2 auswählen und die Formel eingeben:
=LEFT(A2,FIND(" ",A2,1)-1)
Es ist jedoch wichtig zu beachten, dass diese Formel auf einigen Geräten Semikolons anstelle von Kommas verwendet. Wenn die obige Formel für Sie also nicht funktioniert, müssen Sie möglicherweise stattdessen die folgende Version verwenden:
=LEFT(cell;FIND(” “;cell;1)-1)
Im Beispiel würden Sie Folgendes verwenden:
=LEFT(A2,FIND(" ",A2,1)-1)
Jetzt können Sie den Ausfüllgriff einfach nach unten an das Ende der Spalte Vorname ziehen.
Mit der LEFT-Funktion können Sie eine Zeichenfolge beginnend am linken Ende des Textes trennen. Der FIND-Teil dieser Formel findet das erste Leerzeichen im vollständigen Namen, sodass Sie den Teil Ihres vollständigen Namens erhalten, der vor einem leeren Leerzeichen steht.
Daher bleiben Vornamen mit Bindestrich zusammen, ebenso Vornamen, die Sonderzeichen enthalten. Ihre Spalte „Vollständiger Name“ enthält jedoch keine zweiten Vornamen oder zweiten Initialen.
Komma oder Semikolon?
Warum ist die Formel nicht für alle gleich?
Für viele Excel-Benutzer verwenden Excel-Funktionen Kommas, um Eingabedaten zu trennen. Auf einigen Geräten sind die regionalen Einstellungen jedoch unterschiedlich.
Um herauszufinden, welches Symbol von Ihrem Excel verwendet wird, beginnen Sie einfach mit der Eingabe der Formel. Wenn Sie beginnen, geben Sie =LEFT( ein , sehen Sie einen Hover-Text, der die richtige Formatierung vorschlägt.
Nachnamen trennen
Gehen Sie genauso vor, um Nachnamen zu trennen. Dieses Mal sollten Sie die RIGHT-Formel verwenden, die Strings von rechts beginnend trennt.
Die Formel, die Sie benötigen, lautet:
=RIGHT(cell, LEN(cell) – SEARCH(“#”, SUBSTITUTE(cell”, “, “#”, LEN(cell) – LEN(SUBSTITUTE(cell, ” “, “”)))) )
Im obigen Beispiel würden Sie die folgende Formel in Zelle C2 verwenden:
=RIGHT(A2,LEN(A2)-SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ","")))))
Auch hier müssen Sie möglicherweise vom Komma zum Semikolon wechseln, was bedeutet, dass Sie möglicherweise Folgendes verwenden müssen:
=RIGHT(A2;LEN(A2)-SEARCH("#";SUBSTITUTE(A2;" ";"#";LEN(A2)-LEN(SUBSTITUTE(A2;" ";"")))))
Nachnamen mit Bindestrich und Nachnamen mit Sonderzeichen bleiben erhalten.
Warum ist diese Formel komplexer als die für Vornamen? Es ist schwieriger, Zweitnamen und zweite Initialen von Nachnamen zu trennen.
Wenn Sie möchten, dass die zweiten Vornamen und Initialen mit den Nachnamen aufgelistet werden, können Sie die Formel verwenden:
=RIGHT(cell, LEN(cell) – SEARCH(” “, cell))
oder:
=RIGHT(A2,LEN(A2)-SEARCH(" ",A2))
oder:
=RIGHT(A2;LEN(A2)-SEARCH(" ";A2))
Aber was ist, wenn Sie die zweiten Vornamen trennen möchten? Dies ist weniger üblich, aber es kann nützlich sein, es zu wissen.
Zweite Vornamen trennen
Die Formel für Zweitnamen lautet wie folgt:
=MID(Zelle, SUCHE(“ “, Zelle) + 1, SUCHE(“ “, Zelle, SUCHE(“ “, Zelle)+1) – SUCHE(“ “, Zelle)-1)
Im obigen Beispiel erhalten Sie:
=MID(A2,SEARCH(" ",A2)+1,SEARCH(" ",A2,SEARCH(" ",A2)+1)-SEARCH(" ",A2)-1)
Wenn Ihr Excel Semikolons verwendet, lautet die Formel:
=MID(A2;SEARCH(" ";A2)+1;SEARCH(" ";A2;SEARCH(" ";A2)+1)-SEARCH(" ";A2)-1)
Ziehen Sie nach Eingabe der Formel den Ausfüllgriff nach unten. Hier ist eine Spalte für den zweiten Vornamen, die dem obigen Beispiel hinzugefügt wurde:
Wenn der vollständige Name keinen zweiten Vornamen oder Initialen enthält, erhalten Sie in dieser Spalte Nullwerte, die als #WERT! angezeigt werden können. Um leere Zellen anstelle von #WERT! zu erhalten, können Sie die WENNFEHLER-Funktion verwenden.
Dann wird Ihre Formel zu:
=IFERROR(MID(cell, SEARCH(“ “, cell) + 1, SEARCH(“ “, cell, SEARCH(“ “, cell)+1) – SEARCH(“ “, cell)-1)“, “)
oder:
=IFERROR(MID(A2,SEARCH(" ",A2)+1,SEARCH(" ",A2,SEARCH(" ",A2)+1)-SEARCH(" ",A2)-1),"")
oder:
=IFERROR(MID(A2;SEARCH(" ";A2)+1;SEARCH(" ";A2;SEARCH(" ";A2)+1)-SEARCH(" ";A2)-1);"")
Ein Ansatz zur Trennung mehrerer zweiter Vornamen
Was passiert, wenn jemand auf Ihrer Liste mehrere zweite Vornamen hat? Mit der obigen Formel wird nur der erste zweite Vorname abgerufen.
Um dieses Problem zu lösen, können Sie einen anderen Ansatz zum Trennen von Zweitnamen ausprobieren. Wenn Sie die Spalten Vorname und Nachname angelegt haben, können Sie diese einfach abschneiden. Alles, was übrig bleibt, zählt als zweiter Vorname.
Diese Formel lautet:
=TRIM(MID(Zelle1,LEN(Zelle2)+1,LEN(Zelle1)-LEN(Zelle2&Zelle3)))
Hier bezieht sich Zelle1 auf den Zellenzeiger unter der Spalte Vollständiger Name, Zelle2 bezieht sich auf den Zellenzeiger unter der Spalte Vorname, während Zelle3 auf den Zellenzeiger unter der Spalte Nachname verweist. Im obigen Beispiel erhalten wir:
=TRIM(MID(A2,LEN(B2)+1,LEN(A2)-LEN(B2&D2)))
oder:
=TRIM(MID(A2;LEN(B2)+1;LEN(A2)-LEN(B2&D2)))
Wenn Sie sich für diese Formel entscheiden, müssen Sie sich keine Gedanken über Nullwerte machen.
Kurze Zusammenfassung
Hier sind die Formeln, die Sie verwenden können, um vollständige Namen in Teile aufzuteilen:
Vornamen:=LEFT(cell,FIND(” “,cell,1)-1)
Nachnamen:=RIGHT(cell, LEN(cell) – SEARCH(“#”, SUBSTITUTE(cell”, “, “#”, LEN(cell) – LEN(SUBSTITUTE(cell, ” “, “”) ))))
Zweite Vornamen:=IFERROR(MID(cell, SEARCH(“ “, cell) + 1, SEARCH(“ “, cell, SEARCH(“ “, cell)+1) – SEARCH(“ “, cell)-1 ),””)
Alternative Formel für zweite Vornamen: =TRIM(MID(cell1,LEN(cell2)+1,LEN(cell1)-LEN(cell2&cell3)))
Trennung von Vor- und Nachnamen ohne Verwendung von Formeln
Wenn Sie keine Lust haben, eine Reihe von Formeln einzutippen, die möglicherweise falsch eingegeben werden, nutzen Sie den in Excel integrierten Assistenten zum Konvertieren von Text in Spalten.
- Stellen Sie sicher, dass die Daten Registerkarte wird aus dem Menü oben ausgewählt und markieren Sie die Spalte, die Sie konvertieren möchten.
- Klicken Sie dann auf Text in Spalten .
- Stellen Sie als Nächstes sicher, dass getrennt ausgewählt ist, und klicken Sie auf Weiter
. - Wählen Sie jetzt Leertaste aus aus den Optionen und klicken Sie auf Weiter .
- Ändern Sie dann das Ziel zu „$B$2 “ und klicken Sie auf Fertig stellen.
Das Endergebnis sollte so aussehen. 
Ein letztes Wort
Es gibt viele andere Möglichkeiten, dieses Problem in Excel zu lösen. Wenn keine der verfügbaren Optionen Ihren Anforderungen entspricht, recherchieren Sie weiter.
Die Verwendung von Formeln ist relativ einfach und hängt nicht von der verwendeten Excel-Version ab. Aber leider kann es immer noch zu Fehlern kommen.
Wenn beispielsweise der vollständige Name einer Person mit ihrem Familiennamen beginnt, wird er falsch herum aufgeteilt. Die Formeln haben auch Probleme mit Nachnamen, die Präfixe oder Suffixe enthalten, wie z. B. le Carré oder van Gogh. Wenn der Name einer Person auf Jr. endet, wird dies als Nachname aufgeführt.
Es gibt jedoch Modifikationen, die Sie hinzufügen können, um diese Probleme zu lösen, sobald sie auftreten. Die Arbeit mit Formeln gibt Ihnen die Flexibilität, die Sie benötigen, um diese Komplexitäten zu bewältigen.